Update Knowledge Articles in Bulk

Recently we had a big Knowledge Centric Support (KCS) initiative where we generated a ton of Articles for use in a Community. (We're still on Classic Knowledge.)

Problem is, some users forgot to tick the "Customer" box when creating the Articles. So those articles didn't appear to external users in the Community.

You can update these Articles in bulk, but you need to use a few obscure hooks in Apex. This method will create a draft of the Article, update the Knowledge Article Version, and then re-publish without creating a new Version.

The following code will update the 'IsVisibleInCsp' flag for a single Article specified in the 1st query, which will make it visible to Customers.

	// In this example my Knowledge Article Type is "BA Public Knowledgebase" (BA_Public_Knowledgebase__kav)
	// Query for the online version; filter by KA version is optional.
	List<BA_Public_Knowledgebase__kav> baKA = [select id, IsVisibleInCsp, publishstatus, knowledgearticleid from BA_Public_Knowledgebase__kav where PublishStatus = 'Online' and ID = 'kaA2M000003PCxs'];
	Id kaId = baKA[0].KnowledgeArticleId;
	// Create a revision without unpublishing.
	KbManagement.PublishingService.editOnlineArticle(baKA[0].KnowledgeArticleId, false);
	// Requery to get the new version ID.
	baKA = [SELECT Id, KnowledgeArticleId, PublishStatus, IsVisibleInCsp FROM BA_Public_Knowledgebase__kav WHERE KnowledgeArticleId = : kaId and PublishStatus = 'Draft' limit 1];
	// Set to be visible to Customers. There is also IsVisibleInPrm (Partner Community), IsVisibleInApp (internal app), and IsVisibleInPkb (Public KnowledgeBase)
	BA_Public_Knowledgebase__kav newKAV = new BA_Public_Knowledgebase__kav(id = baKA[0].Id, IsVisibleInCsp = true);
	update newKav;
	// Republish without a new version
	KbManagement.PublishingService.publishArticle(kaId, false);

view raw Update_KAV_To_Be_Customer_Facing.apex hosted with ❤ by GitHub

Here's a bulkified version. This is heavy on the CPU so I run it 10 at a time.

When going over these in bulk, you might run into a situation where there is an existing draft of an article that has been previously published; i.e., it's actively being updated. In this example, we search for those situations and don't create revisions of them.

	// Query for the online versions
	// Since this is heavy, process 10 at a time.
	Map<Id,BA_Public_Knowledgebase__kav> kavsToProcess = new Map<Id,BA_Public_Knowledgebase__kav>([select id, Title, IsVisibleInCsp, publishstatus, knowledgearticleid from BA_Public_Knowledgebase__kav where IsLatestVersion = true and publishstatus = 'Online' and IsVisibleInCsp = false limit 10]);
	// Run over the KA Versions and collect the KnowledgeArticle ID's.
	Set<Id> kaIds = new Set<Id>();
	for (BA_Public_Knowledgebase__kav thisKAV : kavsToProcess.values()){
	kaIds.add(thisKAV.KnowledgeArticleId);
	}
	// Query for EXISTING draft versions of our published articles. We'll exclude them from our updates.
	List<BA_Public_Knowledgebase__kav> draftKAVs = [select id, Title, IsVisibleInCsp, publishstatus, knowledgearticleid from BA_Public_Knowledgebase__kav where PublishStatus = 'Draft' and KnowledgeArticleId in : kaIds];
	List<BA_Public_Knowledgebase__kav> toUpdate = new List<BA_Public_Knowledgebase__kav>();
	// Go over the KnowledgeArticleVersions from the 2nd query and create a list (Set) of KnowledgeArticle ID's that
	// have an existing draft.
	Set<Id> kasWithDrafts = new Set<Id>();
	for (BA_Public_Knowledgebase__kav draftKAV : draftKAVs){
	kasWithDrafts.add(draftKav.KnowledgeArticleId);
	System.debug('Eliminating Article From Processing, Already Has Draft: ' + draftKav.Title + ' ' + draftKav.id);
	// If this version doesn't have our flag, add it to the list to update.
	if (draftKav.IsVisibleInCsp == false){
	toUpdate.add(new BA_Public_Knowledgebase__kav(Id = draftKAV.Id, IsVisibleInCsp = true));
	}
	}
	Integer quantityPreExistingDrafts = toUpdate.size();
	System.debug('Will update ' + quantityPreExistingDrafts + ' pre-existing drafts.');
	// Now, go back over the original list of published versions and create an un-versioned revision of any Article that does not
	// have a pre-existing draft.
	for (BA_Public_Knowledgebase__kav thisKAV : kavsToProcess.values()){
	if (!kasWithDrafts.contains(thisKav.KnowledgeArticleId)) {
	System.debug('Updating ' + thisKav.Title);
	KbManagement.PublishingService.editOnlineArticle(thisKAV.KnowledgeArticleId, false);
	}
	}
	// Requery to get all the Knowledge Article VERSION Id's created above from editOnlineArticle().
	// Note that this EXCLUDES the KnowledgeArticles that already have a draft.
	kavsToProcess = new Map<Id,BA_Public_Knowledgebase__kav>([SELECT Id, KnowledgeArticleId, PublishStatus, IsVisibleInCsp FROM BA_Public_Knowledgebase__kav WHERE KnowledgeArticleId IN : kaIds and PublishStatus = 'Draft' and (NOT(Id IN : kasWithDrafts))]);
	// Go over all our newly created versions, and update them with the attribute we're going for (IsVisibleInCsp)
	for (BA_Public_Knowledgebase__kav thisKAV : kavsToProcess.values()) {
	toUpdate.add(new BA_Public_Knowledgebase__kav (Id = thisKAV.Id, IsVisibleInCsp = true));
	}
	update toUpdate;
	// Now publish the new versions that we have updated.
	for (BA_Public_Knowledgebase__kav thisKAV : kavsToProcess.values()){
	KbManagement.PublishingService.publishArticle(thisKAV.KnowledgeArticleId, false);
	}
	System.debug('Total Updated: ' + toUpdate.size());
	System.debug('... ' + quantityPreExistingDrafts + ' pre-existing drafts were updated');
	System.debug('... ' + (toUpdate.size()-quantityPreExistingDrafts) + ' were republished');
	System.debug('Success');

view raw Update_All_Articles.java hosted with ❤ by GitHub

This will go over all articles of type BA_Public_Knowledgebase__kav, 10 at a time. Update the code for your KnowledgeArticleVersion name, then run in Execute Anonymous. When you're done it will report that it updated 0 articles.